Asteroids clone example code

	Asteroids clone example code	Show Index

This page demonstrates the code necessary to create an Asteroids clone. Some of it's features include:

-Images and sounds just like the original
-Asteroids break into smaller and smaller asteroids
-UFO's periodically appear to harass player
-Large UFO's fire in random directions but small UFO's fire directly at player
-Players ship has momentum and 'floats' across the screen
-Player can 'hyperspace' to a random location on the screen
-Player gains an additional life every 10,000 points
-All game objects 'explode' when destroyed

Jump ahead to see the final result...

Asteroids clone - Click to enlarge

Start with setting up graphics:

Graphics 800,600, 0, 1					;2D graphics at a resolution of 800x600
Text 400, 300, "Loading...", 1				;Write a temp message (could display an image here too)

Define Types:

;Define Types						;Use Types to store ship, asteroid, bullet, and particle information
Type ShipTYPE						;Set up the Ship type
	Field ID					;Type of ship (1=Player, 2=Slow UFO, 3=Fast UFO)
	Field X#					;X position
	Field Y#					;Y position
	Field rotation					;Current rotation of ship
	Field XVelocity#				;Ships X velocity
	Field YVelocity#				;Ships Y velocity
End Type
Type BulletTYPE						;Set up the Bullet type
	Field ID					;Type of bullet (1=player's, 2=UFO's)
	Field X#					;X position
	Field Y#					;Y position
	Field XVector#					;X, Y vectors of the bullets rotation, both are used to
	Field YVector#					; reduce the math required when updating the bullets position
	Field life					;Counter to keep track of bullets existence
End Type
Type AsteroidTYPE 					;Set up the Asteroid type
	Field ID					;Type of asteroid (1=Big, 2=Medium, 3=Small)
	Field X#					;X position
	Field Y#					;Y position
	Field rotation					;Current rotation of asteroid
	Field velocity#					;Asteroid velocity
End Type
Type ParticleTYPE					;Set up the Particle type
	Field X#					;X position
	Field Y#					;Y position
	Field XVector#					;X, Y vectors of the particles rotation, both are used to
	Field YVector#					; reduce the math required when updating the particles position
	Field life					;Counter to keep track of the particles existence
End Type

To do:

Unfinished...

And here is the entire code pieced together so that you can copy&paste it and immediately run it to see how it works.
Unfortunately, it doesn't all fit into one text box, so you'll have to add the code in the 2nd text box to the first.

Keys used in this example:

keyboard.jpg (7994 bytes)

Left key	Move left
Right key	Move Right
Up key		Thrust
Down key	Hyperspace
Spacebar	Fire
Esc key		Exits program

Files used in this example:

right click and select "Save Target As..." files used in this example

ship.png	fire.wav
shipFlame.png	bangLarge.ogg
bigA.png	bangMedium.ogg
medA.png	bangSmall.ogg
smallA.png	thrust.wav
slowUFO.png	slowUFO.wav
fastUFO.png	fastUFO.wav
		deepbeat.ogg
		extraShip.wav

;Asteroids example
;by WolRon

Graphics 800,600, 0, 1					;2D graphics at a resolution of 800x600
Text 400, 300, "Loading...", 1			;Write a temp message (could display an image here too)

;Define Types						;Use Types to store ship, asteroid, bullet, and particle information
Type ShipTYPE						;Set up the Ship type
	Field ID							;Type of ship (1=Player, 2=Slow UFO, 3=Fast UFO)
	Field X#							;X position
	Field Y#							;Y position
	Field rotation						;Current rotation of ship
	Field XVelocity#					;Ships X velocity
	Field YVelocity#					;Ships Y velocity
End Type
Type BulletTYPE						;Set up the Bullet type
	Field ID							;Type of bullet (1=player's, 2=UFO's)
	Field X#							;X position
	Field Y#							;Y position
	Field XVector#					;X, Y vectors of the bullets rotation, both are used to
	Field YVector#					; reduce the math required when updating the bullets position
	Field life							;Counter to keep track of bullets existence
End Type
Type AsteroidTYPE					;Set up the Asteroid type
	Field ID							;Type of asteroid (1=Big, 2=Medium, 3=Small)
	Field X#							;X position
	Field Y#							;Y position
	Field rotation						;Current rotation of asteroid
	Field velocity#					;Asteroid velocity
End Type
Type ParticleTYPE					;Set up the Particle type
	Field X#							;X position
	Field Y#							;Y position
	Field XVector#					;X, Y vectors of the particles rotation, both are used to
	Field YVector#					; reduce the math required when updating the particles position
	Field life							;Counter to keep track of the particles existence
End Type

;Create imagestrips for game images that will be rotated
shipImage = LoadImage("ship.png")				;Stores handle to image of players ship
MidHandle shipImage							;'Handle' the ship image at its center (so it will rotate around it's center)
playerStrip = CreateImage(ImageWidth(shipImage), ImageHeight(shipImage), 90)	;Create image strip of 90 tiles
For iter = -45 To 44							;Perform a 'circular' loop (-180° to 176°)
	rotatedImage = CopyImage(shipImage)		;Copy ship image into temporary image
	RotateImage(rotatedImage, iter*4)			;Rotate the temp image (4° intervals)
	SetBuffer ImageBuffer(playerStrip, iter+45)	;Set image strip tile (0-89) to draw to
	DrawBlock rotatedImage, ImageWidth(shipImage)/2, ImageHeight(shipImage)/2	;Draw temp image to (center of) tile
	FreeImage rotatedImage					;Free memory used by temp image
Next
MidHandle playerStrip							;'Handle' the ship image at its center (so it will rotate around it's center)

flameImage = LoadImage("shipFlame.png")		;Stores handle to image of players ship's rocket flame
MidHandle flameImage						;'Handle' the flame image at its center (so it will rotate around it's center)
flameStrip = CreateImage(ImageWidth(flameImage), ImageHeight(flameImage), 90)	;Create image strip of 90 tiles
For iter = -45 To 44							;Perform a 'circular' loop (-180° to 176°)
	rotatedImage = CopyImage(flameImage)		;Copy flame image into temporary image
	RotateImage(rotatedImage, iter*4)			;Rotate the temp image (4° intervals)
	SetBuffer ImageBuffer(flameStrip, iter+45)	;Set image strip tile (0-89) to draw to
	DrawBlock rotatedImage, ImageWidth(flameImage)/2, ImageHeight(flameImage)/2	;Draw temp image to (center of) tile
	FreeImage rotatedImage					;Free memory used by temp image
Next
MidHandle flameStrip							;'Handle' the flame image at its center (so it will rotate around it's center)

;Load images
roidBig = LoadImage("bigA.png")				;Load the image into memory
MidHandle roidBig							;'Handle' the image at its center (so rotations will occur around it's center)
roidMed = LoadImage("medA.png")				;Load the image into memory
MidHandle roidMed							;'Handle' the image at its center (so rotations will occur around it's center)
roidSmall = LoadImage("smallA.png")			;Load the image into memory
MidHandle roidSmall							;'Handle' the image at its center (so rotations will occur around it's center)
slowUFO = LoadImage("slowUFO.png")			;Load the image into memory
MidHandle slowUFO							;'Handle' the image at its center (so rotations will occur around it's center)
fastUFO = LoadImage("fastUFO.png")			;Load the image into memory
MidHandle fastUFO							;'Handle' the image at its center (so rotations will occur around it's center)

;Load Sounds
sndBlast = LoadSound("fire.wav")				;Load the sound into memory
Global sndExplodeLarge = LoadSound("bangLarge.ogg")	;Load the sound and set as Global so it can be played from a function
Global sndExplodeMed = LoadSound("bangMedium.ogg")	;Load the sound and set as Global so it can be played from a function
Global sndExplodeSmall = LoadSound("bangSmall.ogg")	;Load the sound and set as Global so it can be played from a function
sndThrust = LoadSound("thrust.wav")				;Load the sound into memory
sndFastUFO = LoadSound("slowUFO.wav")		;Load the sound into memory
sndSlowUFO = LoadSound("fastUFO.wav")		;Load the sound into memory
sndBeat = LoadSound("deepbeat.ogg")			;Load the sound into memory
sndExtraShip = LoadSound("extraShip.wav")		;Load the sound into memory
;Set up and prime looping sounds
LoopSound sndThrust							;Set thrust sound as a looping type of sound
chnThrust = PlaySound(sndThrust)				;Start the thrust sound so we can assign a channel to it (to be paused/resumed later)
PauseChannel chnThrust						;Immediately pause the channel (so we don't hear it right now)
LoopSound sndSlowUFO						;Set slowUFO sound as a looping type of sound
chnSlowUFO = PlaySound(sndSlowUFO)			;Start the slowUFO sound so we can assign a channel to it (to be paused/resumed later)
PauseChannel chnSlowUFO					;Immediately pause the channel (so we don't hear it right now)
LoopSound sndFastUFO						;Set fastUFO sound as a looping type of sound
chnFastUFO = PlaySound(sndFastUFO)			;Start the fastUFO sound so we can assign a channel to it (to be paused/resumed later)
PauseChannel chnFastUFO					;Immediately pause the channel (so we don't hear it right now)

;Create the players ship
player.ShipTYPE = New ShipTYPE				;Create the players ship
player\ID = 1									;Set ship ID to 1 to represent the player
player\X# = 400								;Set players initial X position to center of screen
player\Y# = 300								;Set players initial Y position to center of screen
player\XVelocity = 0							;Set players initial velocity
player\YVelocity = 0							;Set players initial velocity

SetBuffer BackBuffer()							;Now that everything is set up, set all drawing to the back (unseen) drawing buffer

;Initialize a new game
Global GameOver = False						;All systems are GO!
Global Lives = 3								;Start with 3 ships
Global Score = 0								;Start with a score of zero
Global startingRoids = 4						;Set the number of roids onscreen to start with (increases by 1 every round)
Global last10000 = 0							;Reset the 10,000 increment scoretracker (Player gets new life every 10000 points)
playerHidden = 0								;Set player as visible (any value above zero = hidden)
newShipDelay = 0								;Set to 0 (any value > zero = delay before new enemy ship can appear onscreen)

;Create initial asteroids
CreateAsteroids								;Call the function to create some asteroids
roidDensity = startingRoids * 4					;Calculate the density of the rocks currently onscreen

Gametimer = CreateTimer(60)					;Set and start the game timer (at 60 frames/second)

;Start game loop
While Not KeyHit(1)							;Repeat main loop until the user presses the Esc key
	Cls										;Clear the back buffer to all black so we have a blank canvas to draw on every update
	WaitTimer GameTimer						;Wait for the timer to tick

	;----------------------- Process Inputs --------------------------
	If (Not GameOver) And (Not playerHidden)							;Only bother checking inputs if the player is visible and playing
		;Collect user inputs
		rotateleft = KeyDown(203)	;Left arrow							;It's a good practice to check the state of these inputs only once
		rotateright = KeyDown(205)	;Right arrow							; per game loop. This will prevent odd behaviors from occurring,
		thrust = KeyDown(200)		;Up arrow							; if for example, the state of a key happened to change between
		hyperspace = KeyHit(208)	;Down arrow							; multiple checks of that key while still in the same game loop.
		shoot = KeyHit(57)		;Spacebar
	
		;Apply inputs to player
		If rotateleft And (Not rotateright)									;If left key is pressed but not right key then decrement players rotation
			player\rotation = player\rotation - 4 +360*(player\rotation <= -177); by 4° (but add 360° if already less than -177°)
		EndIf														; (this is to always keep the rotation between -180° and +179°)
		If rotateright And (Not rotateleft)									;If right key is pressed but not left key then increment players rotation
			player\rotation = player\rotation + 4 -360*(player\rotation >= 176) ; by 4° (but subtract 360° if already greater than 176°)
		EndIf														; (this is to always keep the rotation between -180° and +179°)
		
		If thrust														;If thrust key is pressed
			If Abs(player\XVelocity)<4 And Abs(player\YVelocity)<4			;If ship isn't moving faster than maximum allowed
				player\XVelocity = player\XVelocity + .1 * Sin(player\rotation);Increase velocity by 1/10 pixel per frame...
				player\YVelocity = player\YVelocity + .1 * -(Cos(player\rotation))	; ...but adjusted for rotation
			EndIf
		EndIf
		
		If shoot														;If shoot key was pressed
			thisBullet.BulletTYPE = New BulletTYPE						;Create a new bullet
			thisBullet\ID = 1											;Set as the player's bullet
			thisBullet\X# = player\X#									;Set its position the same as the players position
			thisBullet\Y# = player\Y#
			thisBullet\xvector# = Sin(player\rotation) * 6 + (player\XVelocity)	;Set X vector (by adding players velocity to bullets velocity)
			thisBullet\yvector# = -(Cos(player\rotation)) * 6 + (player\YVelocity);Set Y vector (by adding players velocity to bullets velocity)
			thisBullet\life = 80											;Set life of bullet for 80 game loops (about 3/4 distance across screen)
			PlaySound sndBlast										;Play the gunblast sound
		EndIf
		
		If hyperspace
			player\x# = Rnd(0, 800)									;Randomly choose a new X position in space
			player\y# = Rnd(0, 600)									;Same for the Y position
			player\XVelocity = 0										;Set X velocity to zero
			player\YVelocity = 0										;Same for the Y velocity
			playerHidden = 30											;Hide player for 30 game updates (about 1/2 second)
		EndIf
	EndIf
	
	;---------------------- Process Logic ---------------------------
	;Advance players ship
	If Not playerHidden												;Only bother computing if the player is visible
		player\X# = player\X# + player\XVelocity							;Move players ship in X according to ships rotation and velocity
		player\Y# = player\Y# + player\YVelocity							;Move players ship in Y according to ships rotation and velocity
		If player\X# < 0 Then player\X# = 800								;If ship moves offscreen, reposition it on opposite side
		If player\X# > 800 Then player\X# = 0								;If ship moves offscreen, reposition it on opposite side
		If player\Y# < 0 Then player\Y# = 600								;If ship moves offscreen, reposition it on opposite side
		If player\Y# > 600 Then player\Y# = 0								;If ship moves offscreen, reposition it on opposite side
		player\XVelocity = player\XVelocity * .996							;Decay the velocity slightly so ship doesn't drift forever
		player\YVelocity = player\YVelocity * .996							;Decay the velocity slightly so ship doesn't drift forever
	EndIf
	
	;Advance asteroids
	For thisRoid.AsteroidType = Each AsteroidTYPE						;Iterate through each of the asteroids
		thisRoid\X# = thisRoid\X# - thisRoid\velocity * Sin(thisRoid\rotation)	;Move roid in X according to its rot. and vel.
		thisRoid\Y# = thisRoid\Y# + thisRoid\velocity * Cos(thisRoid\rotation)	;Move roid in Y according to its rot. and vel.
		If thisRoid\X# < 0 Then thisRoid\X# = 800							;If roid moves offscreen, reposition it on opposite side
		If thisRoid\X# > 800 Then thisRoid\X# = 0							;If roid moves offscreen, reposition it on opposite side
		If thisRoid\Y# < 0 Then thisRoid\Y# = 600							;If roid moves offscreen, reposition it on opposite side
		If thisRoid\Y# > 600 Then thisRoid\Y# = 0							;If roid moves offscreen, reposition it on opposite side
	Next	
	
	;Advance bullets
	numEnemyShots = 0												;Reset to zero so we can tally how many shots are currently onscreen
	For thisBullet.BulletTYPE = Each BulletTYPE							;Iterate through each of the bullets in play
		If thisBullet\ID > 1 Then numEnemyShots = numEnemyShots + 1		;Increment the EnemyShots tally if its an enemies bullet
		thisBullet\X# = thisBullet\X# + thisBullet\xvector#					;Move bullet in X according to its X vector
		thisBullet\Y# = thisBullet\Y# + thisBullet\yvector#					;Move bullet in Y according to its Y vector
		If thisBullet\X# < 0 Then thisBullet\X# = 800						;If bullet moves offscreen, reposition it on opposite side
		If thisBullet\X# > 800 Then thisBullet\X# = 0						;If bullet moves offscreen, reposition it on opposite side
		If thisBullet\Y# < 0 Then thisBullet\Y# = 600						;If bullet moves offscreen, reposition it on opposite side
		If thisBullet\Y# > 600 Then thisBullet\Y# = 0						;If bullet moves offscreen, reposition it on opposite side
		thisBullet\life = thisBullet\life - 1									;Decrement the bullets life by 1
		If thisBullet\life < 1 Then Delete thisBullet							;If bullet has been around for too long then delete it
	Next
	
	;Advance UFOs (and fire at player)
	For thisShip.ShipTYPE = Each ShipTYPE							;Iterate through each of the enemy ships
		If thisShip\ID > 1												;Determine if this ship is a UFO
			If Rnd(1000) > 900 And numEnemyShots = 0					;Occasionally shoot but only if there isn't already a bullet onscreen
				thisBullet.BulletTYPE = New BulletTYPE					;Create a new bullet
				thisBullet\ID = 2										;Set as a UFO's bullet
				thisBullet\X# = thisShip\X#								;Set its position the same as the UFO's position
				thisBullet\Y# = thisShip\Y#
				If thisShip\ID = 2 Or playerHidden Or GameOver			;If slow UFO (or player isn't onscreen),
					rotation% = Rnd(-180, 179)							; shoot in a random direction
				Else													;Otherwise If this is the fast UFO, aim the bullet at the player
					rotation% = ATan2(player\Y# - thisShip\Y#, player\X# - thisShip\X#);Use ArcTangent2 to get proper angle between objects
					rotation% = rotation% + 90 + Rnd (-10, 10)			;Correct for 90° rotational misalignment and add slight randomness
				EndIf
				thisBullet\xvector# = Sin(rotation%) * 6					;Determine the bullets X vector
				thisBullet\yvector# = -(Cos(rotation%)) * 6					;Determine the bullets Y vector
				thisBullet\life = 50										;Set life of bullet for 50 game loops (about 1/2 distance across screen)
			EndIf
			If thisShip\ID = 3											;If fast UFO then change direction occasionally
				If Rnd(1000) > 990 Or (Abs(thisShip\rotation) <> 90 And Rnd(1000) > 980); especially if it's currently travelling diagonally
					If Abs(thisShip\rotation) <> 90						;If ship is moving diagonally already then...
						rotation% = 0									; return to horizontal
					Else
						rotation% = (Ceil(Rnd(3)) - 2) * 45				;Pick a random 45° value (-45, 0, or 45)
					EndIf
					If thisShip\rotation > 0 Then thisShip\rotation = 90 + rotation	;Keep overall direction of travel in same direction
					If thisShip\rotation < 0 Then thisShip\rotation = -90 + rotation	;Keep overall direction of travel in same direction
				EndIf
			EndIf
			thisShip\X# = thisShip\X# - thisShip\XVelocity * Sin(thisShip\rotation)	;Move ship in X according to its rot. and vel.
			thisShip\Y# = thisShip\Y# + thisShip\YVelocity * Cos(thisShip\rotation)	;Move ship in Y according to its rot. and vel.
			If thisShip\Y# < 0 Then thisShip\Y# = 600						;If ship moves offscreen, reposition it on opposite side
			If thisShip\Y# > 600 Then thisShip\Y# = 0						;If ship moves offscreen, reposition it on opposite side
			If thisShip\X# < 0 Or thisShip\X# > 800						;UFO made it across screen so remove it
				Delete thisShip										;Remove the UFO from the list of ships
				newShipDelay = 120									;Set a 2 second delay before a new ship can appear
			EndIf
		EndIf
	Next
	
	;--------------------  Check for Collisons -----------------------
	playerDied = False												;Reset the playerDied flag

	;Check for bullet collisions with anything
	For thisBullet.BulletTYPE = Each BulletTYPE							;Iterate through each of the bullets in play (both player and UFO bullets)
		bulletDied = False												;Reset bulletDied flag so that loop cycles normally
		For thisRoid.AsteroidType = Each AsteroidTYPE					;Iterate through each roid in play
			If thisRoid\ID = 1 Then roidImage = roidBig					;If roid is a big asteroid then set temp roidImage to match the big roid
			If thisRoid\ID = 2 Then roidImage = roidMed					;If its a medium asteroid then set temp roidImage to match the medium roid
			If thisRoid\ID = 3 Then roidImage = roidSmall					;If its a small asteroid then set temp roidImage to match the small roid
			If thisBullet\X# > thisRoid\X# - ImageWidth(roidImage)/2		;Determine if the bullet's position is within the boundary of the roid
				If thisBullet\X# < thisRoid\X# + ImageWidth(roidImage)/2
					If thisBullet\Y# > thisRoid\Y# - ImageHeight(roidImage)/2
						If thisBullet\Y# < thisRoid\Y# + ImageHeight(roidImage)/2
							Delete thisBullet							;If bullet and roid image collided, remove the bullet from the list of bullets
							ExplodeAsteroid(thisRoid, True)				;Create an explosion at the roids position and collect points for it
							bulletDied = True							;Set flag to skip checking against any ships since this bullet was destroyed
							Exit										;And stop looping through the asteroids since this bullet was destroyed
						EndIf
					EndIf
				EndIf
			EndIf
		Next															;Check against next roid
		If Not bulletDied												;If bullet is still alive (didn't hit an asteroid), then keep checking
			For thisShip.ShipTYPE = Each ShipTYPE					;Iterate through each ship in play
				If thisShip\ID = 1 And thisBullet\ID = 2					;If its the players ship and an enemies bullet
					If (Not playerHidden) And (Not GameOver)			;Player must not be hidden and the game must not be over
						If thisBullet\X# > thisShip\X# - ImageWidth(playerStrip )/2	;Determine if the bullet's position is within the boundary of the ship
							If thisBullet\X# < thisShip\X# + ImageWidth(playerStrip )/2
								If thisBullet\Y# > thisShip\Y# - ImageHeight(playerStrip )/2
									If thisBullet\Y# < thisShip\Y# + ImageHeight(playerStrip )/2
										Delete thisBullet				;If bullet and ship image collided, remove the bullet from the list of bullets
										PlaySound(sndExplodeSmall)	;Play an explosion
										playerDied = True				;Kill the player (set the flag so we can deal with it later in the code)
										Exit							;Stop looping through the ships since this bullet is destroyed
									EndIf
								EndIf
							EndIf
						EndIf
					EndIf
				ElseIf thisShip\ID > 1 And thisBullet\ID = 1				;If its an enemy ship and one of the players bullets
					shipImage = slowUFO								;Set a temp image (shipImage) to match the UFO's image
					If thisShip\ID = 3 Then shipImage = fastUFO	 		;If its a fast UFO then set shipImage accordingly
					If thisBullet\X# > thisShip\X# - ImageWidth(shipImage )/2	;Determine if the bullet's position is within the boundary of the ship
						If thisBullet\X# < thisShip\X# + ImageWidth(shipImage )/2
							If thisBullet\Y# > thisShip\Y# - ImageHeight(shipImage )/2
								If thisBullet\Y# < thisShip\Y# + ImageHeight(shipImage )/2
									Delete thisBullet					;If bullet and ship image collided, remove the bullet from the list of bullets
									PlaySound(sndExplodeLarge)		;Play an explosion
									CreateExplosion(thisShip\X#, thisShip\Y#)	;Create an explosion at the ships position
									If thisShip\ID = 2					;Collect points for it
										Score = Score + 200			;200 for a slow UFO
									Else
										Score = Score + 1000			;1000 for a fast UFO
									EndIf
									Delete thisShip					;Delete the ship now
									newShipDelay = 120				;Set a 2 second delay before a new ship can appear
									Exit								;Stop looping through the ships since this bullet is destroyed
								EndIf
							EndIf
						EndIf
					EndIf
				EndIf
			Next														;Check against next ship
		EndIf
	Next																;Check next bullet
	
	;Check for player collisions with asteroids and UFO's
	If (Not playerHidden) And (Not GameOver)							;Only bother checking if the player is visible and playing
		For thisRoid.AsteroidTYPE = Each AsteroidTYPE					;Iterate through each of the asteroids
			Select thisRoid\ID
				Case 1	;Big roid
					If ImagesOverlap(playerStrip, player\X#, player\Y#, roidBig, thisRoid\X#, thisRoid\Y#)
						playerDied = True								;Kill the player (set the flag so we can deal with it later in the code)
						ExplodeAsteroid(thisRoid, False)				;Create an explosion but don't collect points for it
					EndIf
				Case 2	;Medium roid
					If ImagesOverlap(playerStrip, player\X#, player\Y#, roidMed, thisRoid\X#, thisRoid\Y#)
						playerDied = True								;Kill the player (set the flag so we can deal with it later in the code)
						ExplodeAsteroid(thisRoid, False)				;Create an explosion but don't collect points for it
					EndIf
				Case 3	;Small roid
					If ImagesOverlap(playerStrip, player\X#, player\Y#, roidSmall, thisRoid\X#, thisRoid\Y#)
						playerDied = True								;Kill the player (set the flag so we can deal with it later in the code)
						ExplodeAsteroid(thisRoid, False)				;Create an explosion but don't collect points for it
					EndIf
			End Select
		Next
		For thisShip.ShipTYPE = Each ShipTYPE						;Iterate through each of the UFO's
			Select thisShip\ID
				Case 2	;slow UFO
					If ImagesOverlap(playerStrip, player\X#, player\Y#, slowUFO, thisShip\X#, thisShip\Y#)
						playerDied = True								;Kill the player (set the flag so we can deal with it later in the code)
						CreateExplosion(thisShip\X#, thisShip\Y#)		;Create an explosion at the UFO's position
						Delete thisShip								;Remove the UFO from the list of ships
					EndIf
				Case 3	;fast UFO
					If ImagesOverlap(playerStrip, player\X#, player\Y#, fastUFO, thisShip\X#, thisShip\Y#)
						playerDied = True								;Kill the player (set the flag so we can deal with it later in the code)
						CreateExplosion(thisShip\X#, thisShip\Y#)		;Create an explosion at the UFO's position
						Delete thisShip								;Remove the UFO from the list of ships
					EndIf
			End Select
		Next
	EndIf

	;Check for UFO collisions with asteroids
	For thisShip.ShipTYPE = Each ShipTYPE							;Iterate through each of the ships
		If thisShip\ID > 1												;Only bother checking if the ship is a UFO
			If thisShip\ID = 2											;Set a temp image (shipImage) identical to the current ships image
				shipImage = slowUFO									;If its a slow UFO then set shipImage accordingly
			Else
				shipImage = fastUFO									;If its a fast UFO then set shipImage accordingly
			EndIf
			For thisRoid.AsteroidTYPE = Each AsteroidTYPE				;Iterate through each of the asteroids
				shipDied = False										;Reset the shipDied flag
				Select thisRoid\ID										;Check if the UFOs image and the roids image overlap
					Case 1	;Big roid
						If ImagesOverlap(shipImage, thisShip\X#, thisShip\Y#, roidBig, thisRoid\X#, thisRoid\Y#) Then shipDied = True
					Case 2	;Medium roid
						If ImagesOverlap(shipImage, thisShip\X#, thisShip\Y#, roidMed, thisRoid\X#, thisRoid\Y#) Then shipDied = True
					Case 3	;Small roid
						If ImagesOverlap(shipImage, thisShip\X#, thisShip\Y#, roidSmall, thisRoid\X#, thisRoid\Y#) Then shipDied = True
				End Select
				If shipDied
					CreateExplosion(thisShip\X#, thisShip\Y#)			;Create an explosion at the UFOs position
					Delete thisShip									;Remove the UFO from the list of ships
					newShipDelay = 120								;Set a 2 second delay before a new ship can appear
					ExplodeAsteroid(thisRoid, False)					;Create an explosion for the asteroid but don't collect points for it
					Exit												;Exit the asteroid loop since this UFO is destroyed
				EndIf
			Next
		EndIf
	Next
	
	;--------------- Process players death if necessary ---------------
	If playerDied
		CreateExplosion(player\X#, player\Y#)							;Create an explosion at the players position
		player\X# = 400												;Reset the players position to the middle of the screen
		player\Y# = 300
		player\rotation = 0												;Reset the players rotation to straight up
		player\XVelocity# = 0											;Reset the players velocity to zero
		player\YVelocity# = 0
		playerHidden = 120											;Hide the players ship for 2 seconds
		thrust = False													;Reset any thrust that may have been applied
		Lives = Lives - 1												;Decrement the Lives counter
		If Lives < 1 Then GameOver = True								;Set the GameOver flag if the player has no lives remaining
		playerDied = False											;Reset the playerDied flag
	EndIf
	
	;------------------- Process particles -----------------------
	For thisP.ParticleTYPE = Each ParticleTYPE							;Iterate through the list of particles onscreen
		thisP\X# = thisP\X# + thisP\xvector#								;Move the particle in X according to its X vector
		thisP\Y# = thisP\Y# + thisP\yvector#								;Move the particle in Y according to its Y vector
		thisP\life = thisP\life - 1											;Decrement the particles life counter
		If thisP\life < 1 Then Delete thisP									;Remove the particle from the list of particles if it expired
	Next


	;------------------ Process Additional Game Logic -------------------
	If playerHidden													;If the player is currently hidden,
		playerHidden = playerHidden - 1									; decrement the playerHidden variable every game loop
	EndIf

	If thrust															;If thrust key is pressed,
		ResumeChannel chnThrust										; make some noise
	Else	
		PauseChannel chnThrust										; otherwise, kill the noise
	EndIf
		
	If Score - last10000 > 10000										;Gain extra life if cross a new 10,000 point barrier
		playExtraShipSound = 120										;Set countdown to play the extraship sound multiple times
		Lives = Lives + 1												;Increment the players lives
		last10000 = Score - (Score Mod 10000)							;Keep track of what the score was when extralife was obtained
	EndIf
	
	If playExtraShipSound > 0											;If the player just gained an extra ship
		playExtraShipSound = playExtraShipSound - 1					;Decrement extraship sound variable every game loop
		If playExtraShipSound > 60										;If more than one second remains
			If playExtraShipSound Mod 4 = 0 Then PlaySound sndExtraShip	;Play the extraship sound repeatedly at a fast rate (every 4 game loops)
		Else															;If less than one second remains
			If playExtraShipSound Mod 10 = 0 Then PlaySound sndExtraShip;Play extraship sound repeatedly at a slow rate (every 10 game loops)
		EndIf
	EndIf
	
	If roidDensity < 1													;If all asteroids are demolished, start a new round
		startingRoids = startingRoids + 1								;Add an additional roid to the screen this round
		If startingRoids > 12 Then startingRoids = 12						; but no more than 12 roids onscreen
		CreateAsteroids												;Call the function that will actually create them
	EndIf
	
	If newShipDelay > 0												;If delay isn't up yet
		newShipDelay = newShipDelay - 1								;Decrement ship delay time
	ElseIf roidDensity < 16 And Rnd(1000) > 996							;Else randomly make a UFO appear if there aren't many roids onscreen
		numEnemies = 0												;Reset to zero so we can tally how many enemies are currently onscreen
		For thisShip.ShipTYPE = Each ShipTYPE						;Loop through all of the ships currently onscreen
			If thisShip\ID > 1 Then numEnemies = numEnemies + 1			;If this ship is not the players ship, tally it
		Next
		If numEnemies < 1											;If there are no enemy ships onscreen
			thisShip = New ShipTYPE									;Create one (add a ship to the list of ships)
			thisShip\ID = 2											;Set it as a slow UFO
			thisShip\XVelocity = 1										;Set its velocity
			thisShip\YVelocity = 1
			If Score > 2000 And Rnd(1000)>100							;If score>2000 then create a fast UFO instead (most of the time)
				thisShip\ID = 3										;Set it as a fast UFO
				thisShip\XVelocity = 2									;Set its velocity for a fast UFO
				thisShip\YVelocity = 2
			EndIf
			thisShip\Y# = Rnd(600)									;Set the ships Y position randomly

			If Rnd(1000)>500											;Flip a coin
				thisShip\X# = 0										;Set the ship on the left side of the screen
				thisShip\rotation = -90									;Set the ship to move right
			Else
				thisShip\X# = 800										;Set the ship on the right side of the screen
				thisShip\rotation = 90									;Set the ship to move left
			EndIf
		EndIf
	EndIf

	;------------------------ Paint the screen (and play some audio) ----------------------------
	;Draw particles
	For thisP.ParticleTYPE = Each ParticleTYPE							;Iterate through each particle in the list of particles
		Plot thisP\X#, thisP\Y#											;Draw a dot on the screen at its location
	Next
	
	;Draw asteroids (and count them)									;Since we're iterating through the entire list of roids
	roidDensity = 0													; (and aren't deleting any in the process),
	For thisRoid.AsteroidTYPE = Each AsteroidTYPE						; this is a great time to add them all up
		Select thisRoid\ID												; to determine the asteroid fields density
			Case 1	;Large roid
				DrawImage roidBig, thisRoid\X#, thisRoid\Y#				;Draw the large roids image
				roidDensity = roidDensity + 4							;Add 4 to the asteroid field density
			Case 2	;Medium roid
				DrawImage roidMed, thisRoid\X#, thisRoid\Y#				;Draw the medium roids image
				roidDensity = roidDensity + 2							;Add 2 to the asteroid field density
			Case 3	;Small roid
				DrawImage roidSmall, thisRoid\X#, thisRoid\Y#			;Draw the small roids image
				roidDensity = roidDensity + 1							;Add just 1 to the asteroid field density
		End Select
	Next
	
	;Play deep beat sound
	If (Not playerHidden)												;If player is visible then
		deepbeat = deepbeat - 1										;Decrement the deepbeat sound variable every game loop
		If deepbeat < 1												;If value < 1 then
			PlaySound sndBeat										; play the sound and
			deepbeat = Float(roidDensity)/(startingRoids * 4) * 60			; reset the value based on the number of roids currently onscreen
			If deepbeat < 15 Then deepbeat = 15						; but no less than a value of 15 (so it doesn't play too fast)
		EndIf
	EndIf
	
	;Draw enemy ships (and play their sounds)
	For thisShip.ShipTYPE = Each ShipTYPE							;Iterate through each ship in play
		If thisShip\ID = 2												;Check if it's a slow UFO
			DrawImage slowUFO, thisShip\X#, thisShip\Y#				;Draw the ship at the correct position
			ResumeChannel chnSlowUFO								;make slow UFO sound
		Else
			PauseChannel chnSlowUFO								;kill the slow UFO sound if it wasn't a slow UFO
		EndIf
		If thisShip\ID = 3												;Check if it's a fast UFO
			DrawImage fastUFO, thisShip\X#, thisShip\Y#					;Draw the ship at the correct position
			ResumeChannel chnFastUFO								;make fast UFO sound
		Else
			PauseChannel chnFastUFO								;kill the fast UFO sound if it wasn't a fast UFO
		EndIf
	Next	
	
	;Draw bullets
	For thisBullet.BulletTYPE = Each BulletTYPE							;Iterate through each bullet in the list of bullets
		Plot thisBullet\X#, thisBullet\Y#									;Draw a dot on the screen at its location
	Next	

	;Draw players ship
	If (Not GameOver) And (Not playerHidden)							;Only draw if the player is visible and playing
		DrawImage playerStrip, player\X#, player\Y#, ((player\rotation+180)/4);Draw players ship at ships location with correct rotation
		If thrust Then DrawImage flameStrip, player\X#, player\Y#, ((player\rotation+180)/4)	;Draw ships flame (also rotated to match players ship)
	EndIf
	
	Text 30, 5,  RSet$(Str$(Score), 5)									;Draw players score (right justified) on topleft of screen
	If Lives > 0														;If the player has more than one extra life
		For iter = 1 To Lives											;Iterate for each extra life
			DrawImage playerStrip, 80 - iter * 16, 27, 45					;Draw a ship to represent each life (right justified)
		Next
	EndIf
	 
	Flip																;Flip the back drawing buffer to the front to display it to the player
Wend																;Start game loop over again (unless the While statement wasn't true)


;------------------ End the game --------------------
;Clean up before exiting
FreeImage playerStrip													;Upon exit, free the images from memory...
FreeImage flameStrip
FreeImage shipImage
FreeImage flameImage
FreeImage roidBig
FreeImage roidMed
FreeImage roidSmall
FreeImage slowUFO
FreeImage fastUFO
FreeSound sndBlast													;Free the sounds in memory
FreeSound sndExplodeLarge
FreeSound sndExplodeMed
FreeSound sndExplodeSmall
FreeSound sndThrust
FreeSound sndFastUFO
FreeSound sndSlowUFO
FreeSound sndBeat
FreeSound sndExtraShip
Delete player															;Delete the player
Delete Each ShipTYPE												;And delete all of the objects...
Delete Each BulletTYPE
Delete Each AsteroidTYPE
Delete Each ParticleTYPE
End																	;And that's the end


;-----------------------   Functions --------------------------
Function CreateExplosion(xPos#, yPos#)						;Creates an explosion using particles at the given position
	For iter = 1 To 10													;Loop 10 times to create 10 particles
		thisP.ParticleTYPE = New ParticleTYPE							;Create a new particle
		thisP\X# = xPos# + Rnd(10) - 5									;Randomly set its X position next to given X position
		thisP\Y# = yPos# + Rnd(10) - 5									;Randomly set its Y position next to given Y position
		thisP\XVector# = (Sin(thisP\X# - xPos#) * 5)						;Set X vector facing away from explosions center
		thisP\YVector# = (Sin(thisP\Y# - yPos#) * 5)						;Set Y vector facing away from explosions center
		thisP\life = 30													;Give the particle a lifetime of 30 game updates
	Next
End Function

Function ExplodeAsteroid(thisRoid.AsteroidTYPE, gainPoints)	;Calls CreateExplosion and then creates new, smaller roids if necessary
	CreateExplosion(thisRoid\X#, thisRoid\Y#)							;Create an explosion at the roids position
	Select thisRoid\ID
		Case 1	;Big roid
			thisRoid\ID = 2											;Convert this roid to a smaller (medium) one
			thisRoid\rotation = Rnd(0, 359) - 180							;Randomly set roids rotation to a new rotation
			thisRoid\velocity = .5+Rnd(1.9)								;Randomly set roids velocity to a new velocity
			newRoid.AsteroidTYPE = New AsteroidTYPE					;Create another roid
			newRoid\ID = 2											;Set it to be a medium sized roid as well
			newRoid\X# = thisRoid\X#									;Set its position to be the same as the other one
			newRoid\Y# = thisRoid\Y#
			newRoid\rotation = Rnd(0, 359) - 180						;Randomly set new roids rotation (direction of travel)
			newRoid\velocity = .5+Rnd(1.9)								;Randomly set new roids velocity (pixels per frame)
			PlaySound sndExplodeLarge								;Play an explosion based on its size
			If gainPoints Then Score = Score + 20						;Give the player some points if requested
		Case 2	;Medium roid
			thisRoid\ID = 3											;Convert this roid to a smaller (small) one
			thisRoid\rotation = Rnd(0, 359) - 180							;Randomly set roids rotation to a new rotation
			thisRoid\velocity = .5+Rnd(2.9)								;Randomly set roids velocity to a new velocity
			newRoid.AsteroidTYPE = New AsteroidTYPE					;Create another roid
			newRoid\ID = 3											;Set it to be a small roid as well
			newRoid\X# = thisRoid\X#									;Set its position to be the same as the other one
			newRoid\Y# = thisRoid\Y#
			newRoid\rotation = Rnd(0, 359) - 180						;Randomly set new roids rotation (direction of travel)
			newRoid\velocity = .5+Rnd(2.9)								;Randomly set new roids velocity (pixels per frame)		
			PlaySound sndExplodeMed								;Play an explosion based on its size
			If gainPoints Then Score = Score + 50						;Give the player some points if requested
		Case 3 ;Small roid
			Delete thisRoid											;Small roids are removed from the game
			PlaySound sndExplodeSmall								;Play an explosion based on its size
			If gainPoints Then Score = Score + 100						;Give the player some points if requested
	End Select
End Function

Function CreateAsteroids()									;Creates new asteroids around the borders of the screen
		For iter = 1 To startingRoids									;Set up a loop to create some asteroids
			thisRoid.AsteroidTYPE = New AsteroidTYPE					;Add a new roid to the list of roids
			thisRoid\ID = 1											;Set roid ID to largest asteroid size
			If Rnd(2) > 1												;Flip coin to choose a top/bottom or left/right border
				thisRoid\X# = Rnd(0, 800)								;Randomly set roids initial X position
				thisRoid\Y# = 0										;Set roid to top of screen,
				If Rnd(2) > 1 Then thisRoid\Y# = 600						; or randomly set it to the bottom
			Else														;Roid will be randomly set along the left or right of the screen
				thisRoid\Y# = Rnd(0, 600)								;Randomly set roids initial Y position
				thisRoid\X# = 0										;Set roid to left side of the screen,
				If Rnd(2) > 1 Then thisRoid\X# = 800						; or randomly set it to the right side
			EndIf
			thisRoid\rotation = Rnd(0, 359) - 180							;Randomly set roids rotation (direction of travel)
			thisRoid\velocity# = .5+Rnd(.9)								;Randomly set roids velocity (pixels per frame)
		Next
End Function

	If you've reached this page and there's no index on the left, Click here to show the Index Page